Spelling words from "Merry Christmas"

set fp [open /usr/share/dict/web2]

# The frequencies of letters in "Merry Christmas"
array set max {m 2 e 1 r 3 y 1 c 1 h 1 i 1 s 2 t 1 a 1}

# Each word in the Webster's word list is on a line of its own
while {[gets $fp line] != -1} {
    set word [string tolower [string trim $line]]

    # If it has letters not in Merry Christmas we can't spell it
    if {[regexp {[^merrychristmas]} $word]} then continue

    # Meghan says she's learned that every word must have at least one vowel
    if {![regexp {[eia]} $word]} then continue

    # And, the letter e alone, while probably in the dictionary, doesn't
    # meet her teachers definition of a "word"
    if {$word == "e"} then continue

    array set remaining [array get max]
    set abort_p 0
    foreach letter [split $word ""] {
        # Have we prematurely run out of letters to use?
        # first version had a continue here—to continue the while loop
        # but that'd give us buggy behavior since it would continue the foreach instead
        # (thanks to trev for noticing the problems that caused!)
        if {[incr remaining($letter) -1] == -1} then {
            set abort_p 1
            break
        }
    }
    unset remaining
    if {$abort_p} then continue

    # If we get this far then we know $word is spelled entirely with letters
    # from "Merry Christmas"!
    puts $word
}